# OpenSCAD

**URL:** <https://forum.makerforums.info/t/openscad/94500>\
**Category:** 3D Printing\
**Created:** [December 1, 2025, 10:46pm UTC](https://forum.makerforums.info/t/openscad/94500 "2025-12-01T22:46:57Z")\
**Posts on this page:** 18\
**Page:** 2

<div class="post-metadata">

**Author:** ![WillAdams](https://forum.makerforums.info/user_avatar/forum.makerforums.info/willadams/32/107433_2.png) [@WillAdams](https://forum.makerforums.info/u/WillAdams)\
**Post date:** [December 3, 2025, 3:08pm UTC](https://forum.makerforums.info/t/openscad/94500/21 "2025-12-03T15:08:48Z")

</div>

I just wish that the FreeCAD devs would make OpenSCAD a full-fledged scripting option — seems a natural fit, and would be a great way to get better exports out of it.

---

<div class="post-metadata">

**Author:** ![hennep](https://forum.makerforums.info/user_avatar/forum.makerforums.info/hennep/32/116652_2.png) [@hennep](https://forum.makerforums.info/u/hennep)\
**Post date:** [December 3, 2025, 3:37pm UTC](https://forum.makerforums.info/t/openscad/94500/22 "2025-12-03T15:37:27Z")

</div>

![IMG_20251203_161051__01](https://forum.makerforums.info/uploads/default/original/3X/5/4/5448bcfe894c90f6016d6a590c061ed613dcfe45.jpeg)

 ![IMG_20251203_161106__01](https://forum.makerforums.info/uploads/default/original/3X/d/c/dc6deece3dbcc2a4ba839b19325cef3261ad0075.jpeg)

This is the result of too much time spent with OpenSCAD. But it was a good exercise.

I was not able to create the hole for the nut and the threaded rod in OpenSCAD. I had to load the .stl in Sketchup and draw it myself.  
For some reason OpenSCAD will not cut any sections after the rounding has finished.

> [@mcdanlj](#):
>
> If OpenSCAD was so intuitive that you were able to use it without learning anything

I did have to learn a few things, but after 30+ years of programming professionally I feel more comfortable in a programming environment than a program that is the opposite of intuitive.

I will have a look at the steps Michael showed above, and try to repeat these, and maybe I get used to it…  
sometime.

---

<div class="post-metadata">

**Author:** ![WillAdams](https://forum.makerforums.info/user_avatar/forum.makerforums.info/willadams/32/107433_2.png) [@WillAdams](https://forum.makerforums.info/u/WillAdams)\
**Post date:** [December 3, 2025, 6:06pm UTC](https://forum.makerforums.info/t/openscad/94500/23 "2025-12-03T18:06:01Z")

</div>

My take on OpenSCAD has always been:

> The great thing about OpenSCAD is that it makes it easy to model things which may may be represented by cubes, spheres, and cylinders, mathematically positioned and scaled.
> 
> The awful thing about OpenSCAD is that one’s ability to use it is determined by one’s facility with mathematics and using programming to position and scale cubes, spheres, and cylinders.

---

<div class="post-metadata">

**Author:** ![dougl](https://forum.makerforums.info/user_avatar/forum.makerforums.info/dougl/32/95876_2.png) [@dougl](https://forum.makerforums.info/u/dougl)\
**Post date:** [December 3, 2025, 11:12pm UTC](https://forum.makerforums.info/t/openscad/94500/24 "2025-12-03T23:12:44Z")

</div>

and if you are comfortable typing in data, 10 finger typing helps, then it’s easy.  
You wouldn’t believe the number of people who don’t like typing because they are 2 finger peckers and have to look at the keyboard, the screen, keyboard, screen, repeat.

I too have a coding background, learned to 10 finger type in 10th grade and I’ve been tortured helping or working with other coders who can’t 10 finger type.

OpenSCAD felt really intuitive. But all the added capabilities in FreeCAD are my favorite now.

---

<div class="post-metadata">

**Author:** ![easytarget](https://forum.makerforums.info/user_avatar/forum.makerforums.info/easytarget/32/96333_2.png) [@easytarget](https://forum.makerforums.info/u/easytarget)\
**Post date:** [December 4, 2025, 12:17pm UTC](https://forum.makerforums.info/t/openscad/94500/25 "2025-12-04T12:17:36Z")

</div>

With OpenSCAD The big issue here is that the minkowski() operation only uses a single CPU core, and forms a bottleneck. Memory helps but the number of cores in the machine is irrelevant; it is single-thread speed that matters.

My general rule of thumb is that Intersecting, differencing and extruding operations are cheap, but minkowski is expensive; don’t use more than is necessary. Outlining (hull) falls somewhere in between and is very dependent on the number of points in the hull.

So; working on that principle; here is what I came up with: First I broke the handle into the smallest repeatable unit:

 ![image](https://forum.makerforums.info/uploads/default/original/3X/7/4/7400df602dc9b52625395bda3c8c39c15fbf5538.png)

then minkowski just that:

 ![image](https://forum.makerforums.info/uploads/default/original/3X/8/2/828b7a07b647a22d05d01786adffe39cb701907c.png)

Finally; mirror it and repeat to make a full circle; and add the central shaft + holes to the finished object.

 ![Smooth!](https://forum.makerforums.info/uploads/default/original/3X/e/a/eacf566f2d8d2a0e0ff460edad3901ae440d4b3b.png) ![image](https://forum.makerforums.info/uploads/default/original/3X/0/2/02d44caa349ca572fa1770b59d41e35571a2b787.png)

Rendered at `fn = 90` it takes 3 min 36 sec to preview and is very smooth (the manifold render only takes 2 seconds, the hard work was done in the preview).

I think there is a way to do this much faster using some functional programming to create the body 3d mesh directly. I also wonder if it could be done in PythonSCAD using the ability to extrude with a function on the z-axis.

Code:

```c
/* Handle; Segmented version.
- timings taken for each resolution using a fresh instance (no cache)
fn = 18; // Preview time: 0:00:01.287 : manifold render: 0:00:00.298
fn = 36; // Preview time: 0:00:09.918 : manifold render: 0:00:00.516
fn = 54; // Preview time: 0:00:35.324 : manifold render: 0:00:00.839
fn = 72; // Preview time: 0:01:41.459 : manifold render: 0:00:01.280
fn = 90; // Preview time: 0:03:36.698 : manifold render: 0:00:01.610
*/

fn = 90;

outer_diameter = 70;
inner_diameter = 30;
lob_diameter = 44;
protrusion = 10; // from top
lob_count = 5;
round_radius = 4;
hex_diameter = 13; // in mm between flat sides
nut_depth = 5; // in mm
hole_radius = 4.25; // mm

torus_diameter = (outer_diameter - inner_diameter - round_radius) / 2;
hex_correction = hex_diameter / cos(30) + 0.2; // 0.2 mm tolerance

module segment() { // hard-edged
    R = (outer_diameter - torus_diameter) / 2;
    difference() {
        rotate_extrude(angle = 180 / lob_count, $fn=fn) {
                translate([R, 0])
                circle(r = torus_diameter / 2, $fn=fn);
                translate([hole_radius + round_radius, -torus_diameter / 2])
                square([R - hole_radius - round_radius,torus_diameter]);
        }
        translate([R + lob_diameter/2, 0, -torus_diameter])
        cylinder(h = torus_diameter*2 + round_radius, r = lob_diameter / 2, $fn = fn);
    }
}

module rounded_segment() { // round off
    minkowski() {
        segment();
        sphere( r = round_radius, $fn = fn / 2 );
    }
}

module slice() {
    rounded_segment();
    mirror([0,1,0])
    rounded_segment();
}

module stub() {
    minkowski() {
        cylinder(h = (torus_diameter ) / 2 + protrusion , r = inner_diameter / 2 - round_radius, $fn = fn );
        sphere( r = round_radius, $fn = fn / 2 );
    }
}

module nutcase() {
    translate([0, 0, -round_radius - 0.1]) // M8 hole
    cylinder(h = torus_diameter + protrusion + 0.2, d = 2 * hole_radius, $fn = fn);
    translate([0, 0, torus_diameter/2 + round_radius + protrusion - nut_depth]) // M8 nut
    cylinder(h = nut_depth + 0.2 , d = hex_correction, $fn = 6);
}

module handle() {  
    for (x=[1:lob_count])
        rotate(x*(360/lob_count))
        slice();
    difference() {
        stub();
        nutcase();
    }
}

handle();

```

---

<div class="post-metadata">

**Author:** ![hennep](https://forum.makerforums.info/user_avatar/forum.makerforums.info/hennep/32/116652_2.png) [@hennep](https://forum.makerforums.info/u/hennep)\
**Post date:** [December 4, 2025, 9:37pm UTC](https://forum.makerforums.info/t/openscad/94500/26 "2025-12-04T21:37:08Z")

</div>

We’re nearly there Owen. Reducing the minkowski calculations to half a lob was an excellent idea.  
Different parameters however do not always work:  
With these parameters the hole for the threaded rod is missing. I haven’t analysed the problem yet, bedtime now 🙂

outer\_diameter = 25;  
inner\_diameter = 15;  
lob\_diameter = 40;  
protrusion = 10; // from top  
lob\_count = 3;  
round\_radius = 4;  
hex\_diameter = 5.5; // in mm between flat sides  
nut\_depth = 4; // in mm  
hole\_radius = 1.7; // mm

---

<div class="post-metadata">

**Author:** ![easytarget](https://forum.makerforums.info/user_avatar/forum.makerforums.info/easytarget/32/96333_2.png) [@easytarget](https://forum.makerforums.info/u/easytarget)\
**Post date:** [December 5, 2025, 11:33am UTC](https://forum.makerforums.info/t/openscad/94500/27 "2025-12-05T11:33:29Z")

</div>

Humm, the ‘stub’ module was a bit of a hack.

Try replacing `stub()` and `nutcase()` with these:

```c
module stub() {
    rotate_extrude($fn = fn) intersection () {
        hull() {
            translate([inner_diameter / 2 - round_radius, torus_diameter / 2 + protrusion - round_radius])
            circle(r=round_radius, $fn=fn/2);
            square([inner_diameter / 2, 0.1]);
            square([0.1, torus_diameter / 2 + protrusion]);
        }
        translate([hole_radius,0])
        square([inner_diameter / 2, torus_diameter / 2 + protrusion + round_radius]);
    }
}

module nutcase() {
    translate([0, 0, torus_diameter/2 + protrusion - nut_depth])
    cylinder(h = nut_depth + 0.2 , d = hex_correction, $fn = 6);
}

```

 ![image](https://forum.makerforums.info/uploads/default/original/3X/e/7/e706a7b0c0c65b95535258f9351465154b9d8cad.png)

This should scale properly as the main parameters change. But note that there are plenty of values you can pick that will (essentially) blow the model up.  
(also; note the `intersection()` on the `rotate_extrude()`; not only does it create the hole for the screwthread, it also stops the extrude from blowing up due to a negative offset if the `circle(r=round radius)` is bigger than the X offset it is extruded around (`inner_diameter / 2 - round_radius`))

* * *

It’s worth noting that reducing the lobe count from 5 to 3 with your new values fairly dramatically increases the preview render time; this is because each segment now contains more points for the minkowski.

---

<div class="post-metadata">

**Author:** ![hennep](https://forum.makerforums.info/user_avatar/forum.makerforums.info/hennep/32/116652_2.png) [@hennep](https://forum.makerforums.info/u/hennep)\
**Post date:** [December 5, 2025, 12:45pm UTC](https://forum.makerforums.info/t/openscad/94500/28 "2025-12-05T12:45:10Z")

</div>

Did you really copy all my parameters? Mine looks different:

 ![2025-12-05-133753_2560x1417_scrot](https://forum.makerforums.info/uploads/default/original/3X/a/e/ae4d72b034e509387a95bede4855b5b5304a22db.png)  
I think I’m running in the same problem that in some cases minkowsky rounded parts do not accept intersections.

I understand that with only three lobes the calculation of minkowsky takes more time but try to fit your fingers between the lobes when the diameter is only 25mm with 5 lobes.

---

<div class="post-metadata">

**Author:** ![mcdanlj](https://forum.makerforums.info/user_avatar/forum.makerforums.info/mcdanlj/32/96144_2.png) [@mcdanlj](https://forum.makerforums.info/u/mcdanlj)\
**Post date:** [December 5, 2025, 1:05pm UTC](https://forum.makerforums.info/t/openscad/94500/29 "2025-12-05T13:05:22Z")

</div>

> [@hennep](#):
>
> try to fit your fingers between the lobes when the diameter is only 25mm with 5 lobes

Heh. Here’s a picture that includes the 3d-printed knob I use the most. 12mm OD. My fingers definitely do not fit between the lobes! 😀

 ![image](https://forum.makerforums.info/uploads/default/original/3X/2/d/2dc81e6883a6052c9517b81985c2ae90a8a3ca89.jpeg)

---

<div class="post-metadata">

**Author:** ![easytarget](https://forum.makerforums.info/user_avatar/forum.makerforums.info/easytarget/32/96333_2.png) [@easytarget](https://forum.makerforums.info/u/easytarget)\
**Post date:** [December 5, 2025, 1:47pm UTC](https://forum.makerforums.info/t/openscad/94500/30 "2025-12-05T13:47:02Z")

</div>

> [@hennep](#):
>
> Did you really copy all my parameters? Mine looks different:

yep, copy-n-paste..

I wonder if our code has diverged somewhere; I took the calculations for the lobe cutouts directly from your code posted above:

```c
R = (outer_diameter - torus_diameter) / 2;
... torus extrude here ...
for (i = [0 : lob_count-1]) {
    rotate([0, 0, i * 360 / lob_count])
    translate([R + lob_diameter/2, 0, -torus_diameter])
    cylinder(h = torus_diameter*2, r = lob_diameter / 2, $fn = fn);

```

Since this is done before the `minkowski()` in both cases the ‘real’ radius being cut out is reduced by the `rounding_radius`.  
Try replacing the `translate()` with:  
` translate([R + lob_diameter/2 - round_radius, 0, -torus_diameter])`

Which gives something that looks like what you posted: (you could add it to the circle() radius instead, but doing it on the translate() makes the indents slightly ‘sharper’.

 ![image](https://forum.makerforums.info/uploads/default/original/3X/1/9/193982799a955411e64865451c7c03730176d1f7.png)

> [@hennep](#):
>
> I understand that with only three lobes the calculation of minkowsky takes more time but try to fit your fingers between the lobes when the diameter is only 25mm with 5 lobes.

I know what you mean 😉,  
Incedentally; if you turn `lob_count` _up_ to 12 or 15 you get quite a nice looking knurled nut. Not so great for grip but nice for some applications. And it renders fast even with `fn` turned up to 90+

---

<div class="post-metadata">

**Author:** ![hennep](https://forum.makerforums.info/user_avatar/forum.makerforums.info/hennep/32/116652_2.png) [@hennep](https://forum.makerforums.info/u/hennep)\
**Post date:** [December 5, 2025, 10:36pm UTC](https://forum.makerforums.info/t/openscad/94500/31 "2025-12-05T22:36:49Z")

</div>

@[easytarget](https://forum.makerforums.info/u/easytarget),

Sorry for the late reply. Today, I had to do some preparations for our “sinterklaasviering”. I’ve just returned from Belgium where our family gathered last night.

I changed more than I mentioned. I also changed this line:

> torus\_diameter = 10; //(outer\_diameter - inner\_diameter - round\_radius) / 2;

It makes the indents a bit deeper but it messes up the hole for the threaded rod.

@[mcdanlj](https://forum.makerforums.info/u/mcdanlj),

Is that a potentiometer, or something that needs a bit more force like a threaded rod to squeeze something? Makes a difference, don’t you think.

---

<div class="post-metadata">

**Author:** ![mcdanlj](https://forum.makerforums.info/user_avatar/forum.makerforums.info/mcdanlj/32/96144_2.png) [@mcdanlj](https://forum.makerforums.info/u/mcdanlj)\
**Post date:** [December 6, 2025, 1:51pm UTC](https://forum.makerforums.info/t/openscad/94500/32 "2025-12-06T13:51:29Z")

</div>

> [@hennep](#):
>
> Is that a potentiometer, or something that needs a bit more force like a threaded rod to squeeze something? Makes a difference, don’t you think.

That’s a terminal knob. It has a threaded insert melted into it, and is used to attach a wire using a “spade terminal” where the spade terminal is held between the threaded insert and a nut that is partially embedded in the purple box in the picture.

It’s part of a ham radio antenna system.

I have a wire of a particular length with a spade connector on it to use as an antenna. I put the other end of the wire at the end of a fishing pole or up in a tree, and connect it to that post. I connect a shorter wire to another similar terminal and try to hang it over a bush or twig, or possibly just set it on the ground if I can’t put it in the air. Then I connect the box to my radio with a piece of coax cable. It basically hangs from the elevated wire, so it has to be tight enough to hold the box in place when hanging from the wire, and it’s important that it not slip out while I’m operating.

It’s the BindingKnob in QRPUnun.FCStd here:

> **[Michael K Johnson / QRPUnun · GitLab](https://gitlab.com/mcdanlj/QRPUnun)**
>
> GitLab.com

> [@easytarget](#):
>
> if you turn `lob_count` _up_ to 12 or 15 you get quite a nice looking knurled nut.

That was basically why I posted the picture — knurling is another effective approach to leverage. However, for it to be effective, you probably want a smaller minkowski object, because part of what makes knurling effective is how the edge grips your skin. The size of the grooves in the minuscule knobs, combined with a sufficiently but not painfully sharp edge, has been effective for me in practice as gross knurling.

---

<div class="post-metadata">

**Author:** ![TheRealRandoTechNerd](https://forum.makerforums.info/user_avatar/forum.makerforums.info/therealrandotechnerd/32/120004_2.png) [@TheRealRandoTechNerd](https://forum.makerforums.info/u/TheRealRandoTechNerd)\
**Post date:** [December 7, 2025, 8:13am UTC](https://forum.makerforums.info/t/openscad/94500/33 "2025-12-07T08:13:41Z")

</div>

I was inspired by your post: [https://knobgenerator.com/](https://knobgenerator.com/) I have another link but after purchase I realized its NSFW. Anyways.. try it out I’m sure your modeling will be better but it’s a fun way to play with different designs quickly.

---

<div class="post-metadata">

**Author:** ![hennep](https://forum.makerforums.info/user_avatar/forum.makerforums.info/hennep/32/116652_2.png) [@hennep](https://forum.makerforums.info/u/hennep)\
**Post date:** [December 7, 2025, 12:25pm UTC](https://forum.makerforums.info/t/openscad/94500/34 "2025-12-07T12:25:26Z")

</div>

The reason I started with this script is the knob on the right in the picture below.  
My son bought a herb grinder like this one and asked me to print a new knob.

 ![10012946_photo_1-3964257308](https://forum.makerforums.info/uploads/default/original/3X/8/3/83d89707f0b6a9545a4036ad1d1bbdb84bf2ea8c.png)

The edges of this knob are sharp and when you curl your fingers around it, it does not feel comfortable. I see the same design in your webpage. Maybe an extra choice in the left panel to choose between half round or full, or a “Bottom Edge Rounding” feature, would be an improvement.

---

<div class="post-metadata">

**Author:** ![TheRealRandoTechNerd](https://forum.makerforums.info/user_avatar/forum.makerforums.info/therealrandotechnerd/32/120004_2.png) [@TheRealRandoTechNerd](https://forum.makerforums.info/u/TheRealRandoTechNerd)\
**Post date:** [December 8, 2025, 5:25am UTC](https://forum.makerforums.info/t/openscad/94500/35 "2025-12-08T05:25:56Z")

</div>

Great feedback I will implement the bottom edge rounding option - I could make a slider for amount of rounding. When you say half round and full round could you elaborate or do you just mean that it should be adjustable?

Really happy that you gave it a try! I know it won’t be as good as the models that all of you have created but it can be a nice quick prototyper and then iterate from there - kind of a “shortcut" I’ll be honest none of my projects call for a knob just saw how much fun was being had in this thread and wanted to get in on it! Also feel free to share I’ll be covering the compute on it unless it gets wildly popular and even in that case I’d be so happy to see it used I’ll probably still do so 🙂

---

<div class="post-metadata">

**Author:** ![TheRealRandoTechNerd](https://forum.makerforums.info/user_avatar/forum.makerforums.info/therealrandotechnerd/32/120004_2.png) [@TheRealRandoTechNerd](https://forum.makerforums.info/u/TheRealRandoTechNerd)\
**Post date:** [December 8, 2025, 7:27am UTC](https://forum.makerforums.info/t/openscad/94500/36 "2025-12-08T07:27:02Z")

</div>

Made the requested changes!

> **[Streamlit](https://knobgenerator.com/)**

I’m not all the way happy with the bottom rounding - but I think good enough. If there’s more interest in this I’ll start a new thread since this one is solved. Also that’s an awesome grinder. A nice green transparent knob would be cool! I also added a 32, 64 and 128 knurling for the round knob but it loses resolution at 128 so it just looks round again… I think if I were to iterate further I’d maybe make a donut with lobes option - maybe call it a hennep donut? unless this is already a knob type?

---

<div class="post-metadata">

**Author:** ![easytarget](https://forum.makerforums.info/user_avatar/forum.makerforums.info/easytarget/32/96333_2.png) [@easytarget](https://forum.makerforums.info/u/easytarget)\
**Post date:** [December 11, 2025, 9:50am UTC](https://forum.makerforums.info/t/openscad/94500/37 "2025-12-11T09:50:51Z")

</div>

Delayed reply, apologies. I just want to clarify why this happens:

> [@hennep](#):
>
> I changed more than I mentioned. I also changed this line:
> 
> > torus\_diameter = 10; //(outer\_diameter - inner\_diameter - round\_radius) / 2;
> 
> It makes the indents a bit deeper but it messes up the hole for the threaded rod.

The point here is that `torus_diameter` was originally calculated from the outer and inner diameters (`(outer_diameter - inner_diameter - round_radius) / 2`), which is `3` in the model I posted. Overriding this to `10` makes the ring too ‘fat’ and it intrudes into the centre hole once the rounding is applied.

There are many ways you can set the parameters on this to produce bad, ugly or dysfunctional results. I didnt intend it to be a library function, more just a demo of how to minimize the impact of operations like `minkowski()` on the model render times.

---

<div class="post-metadata">

**Author:** ![mcdanlj](https://forum.makerforums.info/user_avatar/forum.makerforums.info/mcdanlj/32/96144_2.png) [@mcdanlj](https://forum.makerforums.info/u/mcdanlj)\
**Post date:** [September 1, 2026, 11:08pm UTC](https://forum.makerforums.info/t/openscad/94500/38 "2026-09-01T23:08:04Z")

</div>

> [@mcdanlj](#):
>
> At this point, I discovered and [reported a bug](https://github.com/FreeCAD/FreeCAD/issues/25899). I expect the bug is in the OpenCASCADE library that FreeCAD uses for its geometry kernel, rather than in FreeCAD proper.

This _specific_ bug report ended up as a new PR today into OpenCASCADE!

> <https://github.com/Open-Cascade-SAS/OCCT/pull/1518>
>
> \## Summary
> 
> Fix the handling of nearly closed face/face intersection curves wh…en a shared pave already exists immediately inside the curve bounds.
> 
> In the FreeCAD \[issue 25899\](https://github.com/FreeCAD/FreeCAD/issues/25899) case, the intersection curve endpoints are approximately 1.49e-6 apart. The curve already contains a shared pave near its bounds, but separate artificial vertices were retained at each bound. This produced a topologically open section edge and could affect subsequent face classification.
> 
> The updated logic reuses a shared near-bound pave at both ends of the curve, producing the expected closed section edge.
> 
> Before/After:
> \<img width="1800" height="700" alt="image" src="https://github.com/user-attachments/assets/0d0cefa0-7dfb-43c4-b1b2-2fc4fb096fa0" /\>
> 
> 
> \## Changes
> 
> \- Extend \`BOPAlgo\_PaveFiller::PutClosingPaveOnCurve()\` with information about:
> - technological vertices created at the curve bounds;
> - vertices shared with other section curves.
> \- Reuse a shared near-bound pave only when guarded by:
> - endpoint tolerance;
> - tangent alignment;
> - parametric proximity;
> - spatial proximity;
> - valid curve range.
> \- Preserve real vertices already assigned to a curve bound.
> \- Select the nearest eligible shared pave independently of candidate iteration order.
> \- Keep the existing closing-pave behavior as the fallback when no eligible shared pave is found.
> \- Add regression geometry based on the original FreeCAD issue 25899 inputs.
> \- Add GTest and DRAW coverage for the Boolean cut and section topology.
> 
> Related issue: https://github.com/FreeCAD/FreeCAD/issues/25899
> 
> \## Regression Coverage
> 
> Added the following GTests:
> 
> \- \`BRepAlgoAPI\_CutTest.FreeCADIssue\_25899\_NearlyClosedSectionCurve\`
> \- \`BOPAlgo\_PaveFillerClosingTest.PreserveRealBoundPave\`
> \- \`BOPAlgo\_PaveFillerClosingTest.RejectGapOutsideEndpointTolerance\`
> \- \`BOPAlgo\_PaveFillerClosingTest.SelectNearestSharedPave\`
> 
> Added the DRAW regression:
> 
> \- \`bugs modalg\_8 bug\_freecad\_25899\`
> 
> The DRAW regression verifies:
> 
> \- the Boolean cut is valid;
> \- the result contains one solid;
> \- the expected volume is preserved;
> \- the section contains one edge and one shared topological vertex;
> \- the nearly closed section edge is topologically closed.
> 
> Checks performed:
> 
> \- macOS arm64 Release build of \`OpenCascadeGTest\` and \`DRAWEXE\`.
> \- Complete TKBO GTest suite: 303/303 passed.
> \- DRAW regression \`bugs modalg\_8 bug\_freecad\_25899\` completed its modeling and topology checks: the cut result is valid, contains one solid, and the section consists of one edge with one shared topological vertex.
> 
> \- \[x\] Relevant tests were added or updated when applicable.
> \- \[x\] Relevant local tests were run.
> 
> \## CLA Confirmation
> 
> \- \[x\] I confirm that I have read the contribution requirements, and that I have signed and submitted the CLA or I am covered by an approved company CLA.
> 
> CLA ID / submission reference:
> 
> Signed/Submitted; Pending
> 
> \## Review Notes
> 
> The new behavior is intentionally limited to smooth, nearly closed intersection curves with an eligible shared near-bound vertex. Geometrically open curves are rejected using the endpoint tolerance, and existing real bound paves are not replaced.
> 
> The existing \`PutClosingPaveOnCurve()\` entry point remains available and delegates to the extended implementation, so this change does not remove or alter the existing API entry point.
> 
> 
> \<img width="1848" height="1448" alt="image" src="https://github.com/user-attachments/assets/084578ca-4f9e-493a-9ffc-88904a553ccb" /\>

[Previous page](https://forum.makerforums.info/t/openscad/94500.md?page=1)
